摘要：合約編寫可以看出合約需要實現用戶投注生成隨機數發放獎勵獎池余額查詢的功能，接下來編寫我們的合約代碼。總結當前隨機數的實現通過鏈上信息生成，這種生成隨機數的方式容易受到不誠實的節點攻擊。

導讀：
本文旨在引導對 DApp 開發感興趣的開發者，構建一個基于以太坊去中心化應用，通過開發一款功能完備的競猜游戲，邁出 DApp 開發的第一步，通過實例講解 Solidity 語言的常用語法，以及前端如何與智能合約進行交互。
如果正在閱讀的你，從未接觸過 DApp 開發也不要緊，可以先閱讀【區塊鏈上編程：DApp開發簡介】進行前置知識補充。

隨著加密貓、FOMO3D 等游戲的火爆，去中心化應用在游戲領域遍地開花，下面就帶著大家一起開發一款簡單有趣的 DApp 游戲，幫助大家熟悉 DApp 開發。

本 DApp 實現的合約功能：用戶從 0-6 的數字中，任意組合三位數進行投注，合約計算出 3 位隨機數，根據隨機數的組合規則分別給予用戶不同倍數的獎勵，如隨機數為 AAA ，A 等于 6 則獎勵至少 20 倍投注金額，即獎池所有余額；A 不等于 6 則獎勵 5 倍投注金額；隨機數為 AAB，則獎勵 2 倍投注金額；隨機數為 ABC 則不獎勵，同時用戶可查看獎池余額和個人投注記錄。

可以看出合約需要實現用戶投注、生成隨機數、發放獎勵、獎池余額查詢的功能，接下來編寫我們的合約代碼。

新建Lottery.sol合約文件，聲明合約版本，^表示合約編譯版本為 0.4.0 至 0.5.0（不含 0.5.0）。

pragma solidity ^0.4.0;

定義合約基本內容，同時聲明最低投注金額。

contract Lottery {
  uint public betMoney = 10 finney;
}

生成隨機數，通過區塊難度block.difficulty和內置函數keccak256生成隨機數，在EVM中常用的數據存儲位置：memory、storage，函數的參數、返回值默認存儲在memory中，狀態變量默認存儲在storage中，我們可以通過聲明memory、storage改變默認存儲位置，兩者的存儲都需要消耗gas，但storage的開銷遠大于memory。

contract Lottery {
  ...
  function generateRandomNumber() private view returns(uint[]) {
    uint[] memory dices = new uint[](3);
    for (uint i = 0; i < 3; i++) {
      dices[i] = uint(keccak256(abi.encodePacked(block.difficulty, now, i))) % 6 + 1;
    }
    return dices;
  }
  ...
}

獲取合約余額，address類型比較重要的成員屬性主要有balance、transfer，分別為獲取地址余額、轉移eth至該地址，默認eth單位是wei。

contract Lottery {
  ...
  function getBankBalance() public view returns(uint) {
    return address(this).balance;
  }
  ...
}

用戶投注，投注方法需要使用payable關鍵字描述，用來表示可以接收eth；通過msg.sender和msg.value獲得交易發送者地址和當前交易附帶的eth。通常使用require來校驗外部輸入參數，當判定條件為false時，則會將剩余的gas退回，同時回滾交易；assert則用來處理合約內部的邏輯錯誤，當錯誤發生時會消耗掉所有gas，同時回滾交易。

contract Lottery {
  ...
  function bet() public payable {
    uint amount = msg.value;
    require(amount >= betMoney, "bet money not less than 10 finney");
    require(address(this).balance >= amount * 20, "contract money not enough to pay reward");

    uint[] memory dices = generateRandomNumber();
    require(dices.length == 3, "dices illegal");

    address addr = msg.sender;
    bool isReward = false;
    uint reward = 0;

    if ((dices[0] == dices[1]) && (dices[1] == dices[2]) && (dices[0] == 6)) {
      isReward = true;
      reward = address(this).balance;
    } else if ((dices[0] == dices[1]) && (dices[1] == dices[2]) && (dices[0] != 6)) {
      isReward = true;
      reward = amount * 5;
    } else if ((dices[0] == dices[1]) || (dices[0] == dices[2]) || (dices[1] == dices[2])) {
      isReward = true;
      reward = amount * 2;
    }

    if (isReward) {
      addr.transfer(reward);
    }
  }
  ...

定義事件，通過合約內部觸發事件，web3 監聽到事件回調進行相應邏輯處理，從而進行頁面 UI 更新；同時前端也可以通過對應事件名稱獲取日志信息。

contract Lottery {
  ...
  event BetList(
    address addr,
    uint amount,
    bool isReward,
    uint reward,
    uint[] dices
  );

  function bet() public payable {
    ...
    emit BetList(addr, amount, isReward, reward, dices);
  }
  ...

至此，我們已經寫完了合約代碼，前端頁面實現就不在此贅述，主要介紹如何使用 web3 與合約交互，這里使用到的 web3 版本是 1.0，web3 1.0 和 0.2x.x 的 API 調用方式差別較大，1.0 的 API 支持異步調用。

安裝 Metamask 瀏覽器插件后，會在瀏覽器頁面內注入一個 web3 實例。檢測頁面中是否存在 web3 實例，如果不存在則連接自己的實例。

import Web3 from "web3";

if (typeof web3 !== "undefined") {
  web3 = new Web3(web3.currentProvider);
} else {
  web3 = new Web3(new Web3.providers.HttpProvider(NODE_NRL));
}

傳入合約 ABI，合約地址，實例化合約對象。

this.contract = new web3.eth.Contract(
  CONTRACT_ABI,
  CONTRACT_ADDR,
);

調用合約中的投注方法，通過try catch可以捕獲到 Metamask 彈窗取消交易操作。

userBet = async () => {
  try {
    await this.contract.methods
      .bet(
        ...
      )
      .send({
        from: ACCOUNT,
        value: MONEY,
      });
  } catch (error) {
    ...
  }
}

查詢記錄的日志，可以通過指定事件名稱、區塊高度及過濾條件來進行日志查詢，值得注意的是，在合約內不能查詢到日志信息。

queryEvent = async () => {
  const event = await this.contract.getPastEvents(
    EVENT_NAME,
    {
      filter: {},
      fromBlock: 0,
      toBlock: "latest",
    }
  )
}

比如修改用戶投注金額及充值這類敏感操作，就需要管理員的權限來進行操作。同樣地，我們也可以拓展贊助商的功能，通過充值獎池的累計金額排名來展示贊助商的廣告，這里就不做展開了。

定義修飾器，在構造函數里設置管理員地址，將創建合約的賬戶設置為管理員。

contract Lottery {
  ...
  address public owner;

  modifier onlyOwner() {
    require(owner == msg.sender);
    _;
  }

  constructor() public {
    owner = msg.sender;
  }
  ...
}

實現修改投注金額的功能，僅管理員賬戶可觸發。

contract Lottery {
  ...
  function setBetMoney(uint _betMoney) public onlyOwner {
    betMoney = _betMoney;
  }

  function deposit() public payable onlyOwner {}
  ...
}

當前隨機數的實現通過鏈上信息生成，這種生成隨機數的方式容易受到不誠實的節點攻擊。下一篇文章將通過多個實例介紹相應的第三方工具庫的使用（Oricalize、SafeMath、OpenZepplin），生成安全的隨機數。

Solidity

Web3js

Cryptozombies

Coursetro

前置文章：

在區塊鏈上編程：DApp 開發簡介

文 / ielapp
一個簡單的程序員
編 / 熒聲

本文已由作者授權發布，版權屬于創宇前端。歡迎注明出處轉載本文。本文鏈接：https://knownsec-fed.com/2018...

想要訂閱更多來自知道創宇開發一線的分享，請搜索關注我們的微信公眾號：創宇前端（KnownsecFED）。歡迎留言討論，我們會盡可能回復。

歡迎點贊、收藏、留言評論、轉發分享和打賞支持我們。打賞將被完全轉交給文章作者。

感謝您的閱讀。