Gradle構(gòu)建SpringBoot程序依賴管理之依賴版本自動(dòng)控制

劉德剛發(fā)布于2019-08-16 18:25 / 3936人閱讀

摘要：前言體系中很多庫之間相互依賴，但是由于版本之間差異比較大，我們需要比較精確的知道每個(gè)庫的版本對應(yīng)關(guān)系，不然很容易造成庫與庫之間對應(yīng)不上，導(dǎo)致部分功能無效，甚至是異常情況。

前言：Spring體系中很多庫之間相互依賴，但是由于版本之間差異比較大，我們需要比較精確的知道每個(gè)庫的版本對應(yīng)關(guān)系，不然很容易造成“庫”與“庫”之間對應(yīng)不上，導(dǎo)致部分功能無效，甚至是異常情況。程序員排查起來一個(gè)頭兩個(gè)大，本篇文章將介紹如何利用gradle的插件來實(shí)現(xiàn)版本自動(dòng)管理機(jī)制

1、依賴管理

SpringBoot構(gòu)建系統(tǒng)文檔

1、每個(gè)SpringBoot版本都提供了他能支持的依賴清單, 所以開發(fā)中我們不需要在配置文件中指定版本，SpringBoot會(huì)自動(dòng)幫我們管理這些依賴，當(dāng)我們升級(jí)SpringBoot的時(shí)候，SpringBoot所支持的依賴清單也會(huì)自動(dòng)升級(jí)

2、我們在用SpringBoot管理依賴的時(shí)候，可以自定義版本號(hào)覆蓋SpringBoot本身依賴的版本

3、springBoot支持的依賴清單包括Spring所有模塊以及Springboot依賴的第三方庫

4、每個(gè)發(fā)布的SpringBoot版本都與一個(gè)基礎(chǔ)版本的SpringFramework有關(guān)聯(lián)，官方是不建議指定版本的

上述的官方文檔關(guān)于依賴管理的描述，總結(jié)下來就是：
在SpringBoot開發(fā)中，如果使用了依賴管理，那么Spring所有模塊和SpringBoot依賴的第三方庫我們不需要指定版本號(hào)

關(guān)于SpringBoot依賴的第三庫在上述鏈接文檔的這個(gè)部分（點(diǎn)擊POM即可查看）：

??：此處提供 SpringBoot 2.1.6 依賴的三方庫，其他版本自行找到指定版本的文檔查看

2、gradle自動(dòng)依賴

本文重點(diǎn)講解gradle如何配置自動(dòng)依賴，關(guān)于maven配置 點(diǎn)擊這里查看

gradle配置點(diǎn)擊這里

文檔中描述：如果你想使用依賴關(guān)系管理，那么你需要保證你的gradle的版本大于4.4

我們通過實(shí)戰(zhàn)方式，針對gradle配置自動(dòng)依賴管理進(jìn)行說明。

3、實(shí)戰(zhàn)

build.gradle配置

方式一：將SpringBoot插件應(yīng)用于項(xiàng)目，依賴的插件將依賴清單加載到項(xiàng)目中，詳細(xì)見配置中描述（建議直接使用此配置）

plugins {
    //id "java"
    //springboot插件，加入版本，那么Spring相關(guān)依賴，則自動(dòng)加入(當(dāng)使用其他插件的時(shí)候，還會(huì)自動(dòng)加載插件所帶的任務(wù))
    id "org.springframework.boot" version "2.1.6.RELEASE"
    //第一種引入方式：寫在此處，需要手動(dòng)設(shè)置依賴管理的版本，否則無法執(zhí)行（手動(dòng)指定版本，好處是插件集中管理在plugins里面）
//    id "io.spring.dependency-management" version "1.0.8.RELEASE"
}
apply plugin: "java"
//第二種引入方式：應(yīng)用依賴管理插件，自動(dòng)給插件追加版本號(hào)（建議使用此配置）
apply plugin: "io.spring.dependency-management"

sourceCompatibility = 1.8

repositories {
    mavenLocal()
    maven{ url "http://maven.aliyun.com/nexus/content/groups/public/"}
}
//設(shè)置commons-pool2版本為"2.6.1"，Spring依賴的是2.6.2
ext["commons-pool2.version"] = "2.6.1"
dependencies {
    //Spring模塊
    compile("org.springframework.boot:spring-boot-starter-web")
    //Spring依賴的第三方模塊(2.1.6依賴的是3.8.1)
    compile("org.apache.commons:commons-lang3")
    //Spring依賴的第三方模塊(2.1.6依賴的是2.6.2)指定依賴版本為2.6.1
    compile("org.apache.commons:commons-pool2")
    //未被依賴的庫需要手動(dòng)：我司開源的 輕代碼開發(fā)框架核心包，文末源碼鏈接
    compile("com.diboot:diboot-core:2.0.0")
}

方式二：如果你僅僅是為了要依賴管理，而不需要插件的功能，你可以使用SpringBootPlugin提供的BOM_COORDINATES來進(jìn)行依賴管理控制也可以達(dá)到效果

plugins {
    //依賴springboot插件，但是不應(yīng)用
    id "org.springframework.boot" version "2.1.6.RELEASE" apply false
}
apply plugin: "java"
apply plugin: "io.spring.dependency-management"
//使用SpringBootPlugin提供的依賴插件
dependencyManagement {
    imports {
        mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
    }
}

sourceCompatibility = 1.8

repositories {
    mavenLocal()
    maven{ url "http://maven.aliyun.com/nexus/content/groups/public/"}
}
//設(shè)置commons-pool2版本為"2.6.1"，Spring依賴的是2.6.2
ext["commons-pool2.version"] = "2.6.1"
dependencies {
    //Spring模塊
    compile("org.springframework.boot:spring-boot-starter-web")
    //Spring依賴的第三方模塊(2.1.6依賴的是3.8.1)
    compile("org.apache.commons:commons-lang3")
    //Spring依賴的第三方模塊(2.1.6依賴的是2.6.2)指定依賴版本為2.6.1
    compile("org.apache.commons:commons-pool2")
    //未被依賴的庫需要手動(dòng)：我司開源的 輕代碼開發(fā)框架核心包，文末源碼鏈接
    compile("com.diboot:diboot-core:2.0.0")
}

4、總結(jié)

Spring相關(guān)模塊，以及SpringBoot依賴的庫可以通過依賴管理，自動(dòng)獲取最適合的庫版本
未加入SpringBoot依賴清單的庫，版本號(hào)不可省略，需要手動(dòng)設(shè)置版本
版本依賴管理是開發(fā)中基礎(chǔ)環(huán)節(jié)，使用版本管理有效減少版本依賴的校對，可以提高開發(fā)效率

diboot 簡單高效的輕代碼開發(fā)框架